Getting Sirius About Time

The ancients didn't use the stars much for time keeping because it's much more complicated than using the sun or moon. Planets wander around, comets zip around. And, there are so many stars! But, all those stars must mean something, so ...

to start:

At this point, you can calculate a current star time-of-day. But, since the stars are forever, you should extend your calculation for more than a few mere centuries from the present. So, you really must

And, when you want to see the Sirius year as the pyramids saw it, you will also have to

Then, you have to choose your data. Here is where I got mine:

Based on this data, it appears that the current Sirius year began approximately at 0540 UT 25 August 9967 BC Gregorian, and will have a length of about 9 327 011.52 Sirius days.

Further work is planned to refine these values and to organize this year into suitable subdivisions.

John Sankey


This rather crude program calculates the Sirius Calendar. I use QuickBasic, but it is designed to also run (with reduced precision) under 16-bit Basica or GW Basic. Hey, it's a lot simpler than astrology! And, I'll bet it gives more accurate predictions too  :-)
10 REM Calculate Sirius Time
20 REM The Sirius Calendar contains days and years.
30 REM The Sirius day is a bit less than 24 hours solar time,
40 REM   the year a bit more than 25 000 solar years.
50 REM The data used are chosen to give optimal accuracy over the
60 REM   year about Y2K (0000 UT 1 Jan 2000 AD Gregorian)
70 REM -----------------------------------------------------------
80 DEFDBL A-Z  :REM this sets QuickBasic to high precision (IEEE) mode
90 REM                as does the # suffix on constants.
100 REM % suffix on variables sets integer type; non-# constants are integer.
110 REM The BASIC INT function returns the integer less than its argument
120 REM   e.g. INT(3.1)=3; INT(-2.2)=-3
130 REM ***** data at IAU J2000.0 *****
140 P0=75.621#                  :REM station longitude, degrees W of Greenwich
150 L0=45.43#                   :REM   geodetic latitude, degrees N of equator
160 G0=5#                       :REM   time zone, hours after UT
170 S1=6.7525#                  :REM Sirius RA 6h45m8.9s
180 S2=-16.716#                 :REM   declination -16d42'58"
190 M1=-.54601#                 :REM   proper motion RA as/yr
200 M2=-1.22308#                :REM     dec as/yr
210 R0=24110.54841#             :REM sidereal offset seconds
220 R1=8640184.812866#          :REM   offset rate seconds/century
230 R9=.0027379094#             :REM siderealday/solarday -1
240 Z0=-119.6510681407965# :REM start of Sirius year, Julian centuries
250 REM ***** get sidereal time offset at day start *****
260 REM Seen from above the earth north pole, the rotation of the earth
270 REM   about its axis is +ve (CCW) period 24- h.
280 REM Its orbit about the sun is +ve, period 365+ solar days,
290 REM   so the Sirius day is shorter than the solar day.
300 REM Add 1 year to Gregorian dates if BC e.g. use Y%=-9 for 10 B.C.
310 REM   there is no year 0 in the Gregorian system
320 D$=DATE$                    :REM this is how Basic gets
330 Y%=VAL(MID$(D$,7))          :REM todays year YYYY
340 M%=VAL(MID$(D$,1,2))        :REM todays month (1:12)
350 D%=VAL(MID$(D$,4,2))        :REM and todays day (1:*)
360 PRINT "Gregorian date";Y%;"yr";M%;"mo";D%;"da"
370 REM find solar days from Y2K
380 Y1%=Y%-2000                 :REM years since Y2K
390 J%=INT((Y1%+3#)/4#)-INT(Y1%/100#)+INT(Y1%/400#)
400 FOR I%=2 TO M%              :REM add days in each complete month to date
410  J%=J%+VAL(MID$("3128313031303131303130",I%*2-3,2))
420 NEXT I%
430 IF INT(Y%/4)*4<>Y% THEN 470    :REM this year not a leap year
440 IF INT(Y%/400)*400=Y% THEN 460 :REM this year is a leap year
450 IF INT(Y%/100)*100=Y% THEN 470 :REM this year not a leap year
460 IF M%>2 THEN J%=J%+1
470 J%=J%+D%-1                  :REM add day of the month
480 J=J%+Y1%*365#               :REM add year factor
490 REM The IAU sidereal equation includes terms for high powers of J.
500 REM   These are a numerical fit to near-epoch precession effects,
510 REM   and do not apply to long term time scales.
520 R=(R1*J/36525#+R0)/3600#
530 T=R: T$="sidereal offset": GOSUB 900
540 REM ***** get time of day (hr) *****
550 D$=TIME$        :REM this is how Basic gets the time
560 H%=VAL(MID$(D$,1,2))        :REM hour (0:23)
570 M%=VAL(MID$(D$,4,2))        :REM minute (0:59)
580 S%=VAL(MID$(D$,7,2))        :REM and second (0:59)
590 G=((S%/60#)+M%)/60#+H%
600 T=G: T$="civil time": GOSUB 900
610 L=G+G0-P0/15#
620 T=L: T$= "local solar time": GOSUB 900
630 PRINT "solar days from local Y2K ";J+L/24#
640 T0=(J-.5#+(G+G0)/24#)/36525# :REM Julian centuries from J2000.0
650 REM ***** get position of Sirius *****
660 REM spherical trigonometry is in radians and Julian centuries
670 P=3.1415926536#
680 REM proper motion of Sirius - change in RA affects time
690 REM   because it is a movement relative to the average
700 REM   star position used to determine IAU sidereal time.
710 REM   change in dec affects cycle
720 REM A is epoch earth pole, B epoch star, C star
730 Z1=S1/12#*P                 :REM star RA at epoch
740 Z2=(90#-S2)/180#*P          :REM   polar angle c
750 Z3=M1*P/6480#               :REM   RA proper motion rate
760 Z4=M2*P/6480#               :REM   dec proper motion rate
770 Z5=SQR(Z3*Z3+Z4*Z4)*T0      :REM proper motion a
780 Z6=ATN(Z3/Z4)               :REM B
790 Q=COS(Z2)*COS(Z5)+SIN(Z2)*SIN(Z5)*COS(Z6)
800 Z7=ATN(SQR(1-Q*Q)/ABS(Q))   :REM cosine rule b (new polar angle)
810 Q=SIN(Z6)/SIN(Z7)*SIN(Z5)
820 Z8=-SGN(T0)*ATN(ABS(Q)/SQR(1-Q*Q)) :REM sine rule A (change in RA)
830 S=(Z1+Z8)/P*12#             :REM current star hour angle
840 T=R+(L+S)*(1#+R9)
850 T$="Sirius local time": GOSUB 900
860 J1=(J-.5#+L/24#-Z0*36525#)*(1#+R9)
870 PRINT "Sirius Day ";J1
880 IF LEN(INKEY$)=0 THEN 880 :REM wait until a key is hit
890 GOTO 980
900 REM output time T title T$ 
910  IF T>=24# THEN T=T-24#: GOTO 910
920  IF T<0# THEN T=T+24#: GOTO 920
930  H%=INT(T)
940  M%=INT((T-H%)*60#)
950  S%=INT((T-H%-M%/60#)*3600#)
960  PRINT T$;H%;"h";M%;"m";S%;"s"
980 END